控件灰化不立即生效，是什么原因？

学习  悬赏: 5 金币

发布:2017-10-16 08:51:17 分类:问答

• Admin    

  Time:2017-10-16 08:55:57

  mainForm.button.disabled = 1
  
  mainForm.listview.disabled = 1
  
      
  
  win.delay(2000)
  
      
  
  mainForm.button.disabled = 0
  
  mainForm.listview.disabled = 0

  sleep是CPU睡眠了，win.delay()是用CPU时钟到某个时间再执行，有区别的吧？

  设计视图里把控件设置为禁用，再切换到代码视图，发现禁用的值应该是数字
• 学习    

  Time:2017-10-16 09:10:49
  感谢指教！
  
  我的本意不是sleep的问题，是禁用后执行一段时间的操作，然后恢复，但在执行操作的过程中，没有灰化，比如下面这样
  

      mainForm.button.disabled = true
  
      mainForm.listview.disabled = true
  
      
  
      http = inet.whttp()
  
      for(i=1;100000;1){
  
          http.get("http//www.sina.com")
  
      }
  
      
  
      mainForm.button.disabled = false
  
      mainForm.listview.disabled = false

  这是什么原因呢？该怎么做才能在执行禁用语句后立即生效？
  
• Admin    

  Time:2017-10-16 09:36:55
  disabled = true 改为 disabled = 1
  
  disabled = false 改为 disabled = 0
  
  sleep(2000) 改为 win.delay(2000)
• Jacen.He    被采纳

  Time:2017-10-16 09:47:09

  http = inet.whttp()
  
  for(i=1;100000;1){
  
      http.get("http//www.sina.com")
  
  }

  你后面写的这段代码，跟sleep函数是一样的，都会让界面失去响应（让界面消息循环停止，也就是win.loopMessage函数被暂停 ），所以你看不到灰化。
  
  耗时的代码放到多线程里就不会有这些问题，或者你可以调用 mainForm.listview.redraw(); 立即重绘就可以。
  
  Admin 说的 disabled = true 改为  disabled = 1 这个是错的，1和true是等价的布尔值，设计器里写成1是为了生成的代码尽可能的短（因为这个代码一般是给设计器看的），平时不用这样写（因为是给自己看的，写true更容易理解）。
• 学习    

  Time:2017-10-16 09:47:09
  大神，我这里效果一样啊，是我系统的原因吗

      mainForm.button.disabled = 1
  
      mainForm.listview.disabled = 1
  
      http = inet.whttp()
  
      for(i=1;100000;1){
  
          http.get("http//www.sina.com")
  
      }
  
      mainForm.button.disabled = 0
  
      mainForm.listview.disabled = 0

• Jacen.He    

  Time:2017-10-16 09:53:15
  正确的加个后台线程，这样写：

  import win.ui;
  
  /*DSG{{*/
  
  mainForm = win.form(text="父窗口";right=759;bottom=469)
  
  mainForm.add(
  
  button={cls="button";text="button";left=147;top=320;right=293;bottom=363;z=1};
  
  button2={cls="button";text="button2";left=386;top=312;right=544;bottom=363;z=2};
  
  listview={cls="listview";left=192;top=104;right=476;bottom=246;edge=1;z=3}
  
  )
  
  /*}}*/
  
  
  
  mainForm.listview.threadCallable();
  
  mainForm.listview.insertColumn("test",300);
  
  mainForm.button2.oncommand = function(id,event){
  
    
  
      mainForm.button.disabled = true
  
      mainForm.listview.disabled = true
  
      
  
      win.invoke(
  
          function(mainForm,url){
  
              import inet.http;
  
              var http = inet.http()
  
              for(i=1;100;1){
  
                  var str  = http.get(url)
  
                   mainForm.listview.addItem( string.left(str,10) )
  
              }
  
          } ,mainForm,"http://www.sina.com"
  
      )
  
      
  
      mainForm.button.disabled = false
  
      mainForm.listview.disabled = false
  
  }
  
  
  
  mainForm.show() 
  
  return win.loopMessage(); 
  
  

• Jacen.He    

  Time:2017-10-16 09:54:07
  或者这样写：

  import win.ui;
  
  /*DSG{{*/
  
  mainForm = win.form(text="父窗口";right=759;bottom=469)
  
  mainForm.add(
  
  button={cls="button";text="button";left=147;top=320;right=293;bottom=363;z=1};
  
  button2={cls="button";text="button2";left=386;top=312;right=544;bottom=363;z=2};
  
  listview={cls="listview";left=192;top=104;right=476;bottom=246;edge=1;z=3}
  
  )
  
  /*}}*/
  
  
  
  mainForm.button2.oncommand = function(id,event){
  
      mainForm.button.disabled = true
  
      mainForm.listview.disabled = true
  
      mainForm.redraw();
  
      
  
      sleep(2000)
  
      mainForm.button.disabled = false
  
      mainForm.listview.disabled = false
  
  }
  
  
  
  mainForm.show() 
  
  return win.loopMessage(); 

• 学习    

  Time:2017-10-16 09:54:49
  Jacen.He，非常感谢！
  
  mainForm.listview.redraw() 生效
  
  但 mainForm.button.redraw() 无效，这是为什么呢
  
• 学习    

  Time:2017-10-16 09:56:10
  我这里 mainForm.redraw() 对button也不起作用，是不是我系统或环境的问题
  
• 学习    

  Time:2017-10-16 09:57:59
  后台线程有效，已学习，非常感谢！
• Jacen.He    

  Time:2017-10-16 09:58:16
  你在后面加一个 win.delay(100)
• 学习    

  Time:2017-10-16 10:03:36
  这下成了，这是什么原因呢