aardio编程中win.dlg.message库的自定义图标颜色怎么用?_电脑编程入门教程

Admin  悬赏: 5 金币

发布:2018-04-28 20:29:31 分类:问答

import win.ui;

/*DSG{{*/

var winform = win.form(text="简码编程 jianma123.com";right=373;bottom=210)

winform.add(

plus={cls="plus";text="显示简单提示框";left=112;top=90;right=248;bottom=120;font=LOGFONT(h=-16);notify=1;z=1}

)

/*}}*/



import win.dlg.message;

var msgDlg = win.dlg.message(winform); 

msgDlg.bgcolor = 0xffffff;

msgDlg.textColor = 0x000000;

msgDlg.fadeInterval = 0;



msgDlg.iconColor = 0xFF0000;//设置图标颜色无效?怎么设置?



msgDlg.buttonStyle = { 

    color = {  

        hover = 0xFF000000;

        active = 0xFF000000; 

        default = 0xFF000000;

    } 

}



msgDlg.titlebarStyle = { 

    color = { 

        hover = 0xff000000;

        active = 0x33000000; 

        default = 0x66000000; 

    }

} 



winform.plus.skin(msgDlg.buttonStyle)

winform.plus.oncommand = function(id,event){

    if( msgDlg.ask("你觉得这个简单提示框好用吗")  ){

          msgDlg.smile("谢谢！")//图标颜色不是我上面设置的颜色,要怎么设置?

    }

    else {

        msgDlg.frown('很遗憾你会这么想,但是\nwin.dlg.message提供了很多自定义外观样式的选项\n您可以根据自己的喜好进行调整')

    }    

}



winform.show() 

win.loopMessage();

• Admin    

  Time:2018-04-28 20:47:46
  把win.dlg.message库里的

  this.iconColor = 0xD4883B; 

  改成

  this.iconColor := 0xD4883B; 

  就有效果了

  感谢群友daheian

  ask = function(msg){ 
  
          this.icon = '\uF059'/*_FA_EXCLAMATION*/
  
          this.iconColor := 0xD4883B;//改成这样
  
          return this.doModal(msg,true);
  
      }

  
  
• daheian    

  Time:2018-04-28 20:56:48
  不客气。
• Admin    

  Time:2018-04-28 22:36:39
  感谢群友console.log补充:

  import win.ui;
  
  /*DSG{{*/
  
  var winform = win.form(text="aardio form";right=759;bottom=469)
  
  winform.add(
  
  button={cls="button";text="button";left=95;top=136;right=238;bottom=237;z=1}
  
  )
  
  /*}}*/
  
  
  
  winform.button.oncommand = function(id,event){
  
      import win.dlg.message;
  
      var msgDlg = win.dlg.message(winform); 
  
      msgDlg.icon = '\uF05A';
  
      msgDlg.iconColor = 0x0000ff;
  
      msgDlg.textColor = 0xFFFFFF;
  
      msgDlg.bgcolor = 0x564A45;
  
      msgDlg.show("先自定义图标,再定义图标颜色,就有图标颜色了")
  
  }
  
  
  
  winform.show() 
  
  win.loopMessage();